first commit

2025-03-06 11:15:32 +01:00
commit 7b30d6e298
5276 changed files with 2108927 additions and 0 deletions
--- a/libraries/Rtc_by_Makuna/examples/DS3231_StoreIt/DS3231_StoreIt.ino
+++ b/libraries/Rtc_by_Makuna/examples/DS3231_StoreIt/DS3231_StoreIt.ino
@@ -0,0 +1,163 @@
+
+// CONNECTIONS:
+// DS3231 SDA --> SDA
+// DS3231 SCL --> SCL
+// DS3231 VCC --> 3.3v or 5v
+// DS3231 GND --> GND
+
+/* for software wire use below
+#include <SoftwareWire.h>  // must be included here so that Arduino library object file references work
+#include <RtcDS3231.h>
+
+SoftwareWire myWire(SDA, SCL);
+RtcDS3231<SoftwareWire> Rtc(myWire);
+ for software wire use above */
+
+/* for normal hardware wire use below */
+#include <Wire.h> // must be included here so that Arduino library object file references work
+#include <RtcDS3231.h>
+RtcDS3231<TwoWire> Rtc(Wire);
+/* for normal hardware wire use above */
+
+// handy routine to return true if there was an error
+// but it will also print out an error message with the given topic
+bool wasError(const char* errorTopic = "")
+{
+    uint8_t error = Rtc.LastError();
+    if (error != 0)
+    {
+        // we have a communications error
+        // see https://www.arduino.cc/reference/en/language/functions/communication/wire/endtransmission/
+        // for what the number means
+        Serial.print("[");
+        Serial.print(errorTopic);
+        Serial.print("] WIRE communications error (");
+        Serial.print(error);
+        Serial.print(") : ");
+
+        switch (error)
+        {
+        case Rtc_Wire_Error_None:
+            Serial.println("(none?!)");
+            break;
+        case Rtc_Wire_Error_TxBufferOverflow:
+            Serial.println("transmit buffer overflow");
+            break;
+        case Rtc_Wire_Error_NoAddressableDevice:
+            Serial.println("no device responded");
+            break;
+        case Rtc_Wire_Error_UnsupportedRequest:
+            Serial.println("device doesn't support request");
+            break;
+        case Rtc_Wire_Error_Unspecific:
+            Serial.println("unspecified error");
+            break;
+        case Rtc_Wire_Error_CommunicationTimeout:
+            Serial.println("communications timed out");
+            break;
+        }
+        return true;
+    }
+    return false;
+}
+
+void setup () 
+{
+    Serial.begin(115200);
+
+    Serial.print("compiled: ");
+    Serial.print(__DATE__);
+    Serial.println(__TIME__);
+
+    //--------RTC SETUP ------------
+    // if you are using ESP-01 then uncomment the line below to reset the pins to
+    // the available pins for SDA, SCL
+    // Wire.begin(0, 2); // due to limited pins, use pin 0 and 2 for SDA, SCL
+    
+    Rtc.Begin();
+#if defined(WIRE_HAS_TIMEOUT)
+    Wire.setWireTimeout(3000 /* us */, true /* reset_on_timeout */);
+#endif
+
+    RtcDateTime compiled = RtcDateTime(__DATE__, __TIME__);
+    printDateTime(compiled);
+    Serial.println();
+
+    if (!Rtc.IsDateTimeValid()) 
+    {
+        if (!wasError("setup IsDateTimeValid"))
+        {
+            Serial.println("RTC lost confidence in the DateTime!");
+            Rtc.SetDateTime(compiled);
+        }
+    }
+
+    if (!Rtc.GetIsRunning())
+    {
+        if (!wasError("setup GetIsRunning"))
+        {
+            Serial.println("RTC was not actively running");
+        }
+    }
+    else
+    {
+        Serial.println("RTC is actively running");
+    }
+
+    RtcDateTime now = Rtc.GetDateTime();
+    if (!wasError("setup GetDateTime"))
+    {
+        if (now < compiled)
+        {
+            Serial.println("RTC is older than compile time, updating DateTime");
+            Rtc.SetDateTime(compiled);
+        }
+    }
+
+    // never assume the Rtc was last configured by you, so
+    // just clear them to your needed state
+    Rtc.Enable32kHzPin(false);
+    wasError("setup Enable32kHzPin");
+    Rtc.SetSquareWavePin(DS3231SquareWavePin_ModeNone); 
+    wasError("setup SetSquareWavePin");
+}
+
+void loop () 
+{
+    RtcDateTime now = Rtc.GetDateTime();
+    if (!wasError("loop GetDateTime"))
+    {
+        printDateTime(now);
+        Serial.println();
+    }
+
+    for(;;)
+    {
+        Rtc.SetIsRunning(false);
+        if (!wasError("loop SetIsRunning"))
+        {
+            Serial.println(">>> Rtc ready for storage <<<");
+        }
+
+        delay(10000); // ten seconds
+    }
+}
+
+#define countof(a) (sizeof(a) / sizeof(a[0]))
+
+void printDateTime(const RtcDateTime& dt)
+{
+	char datestring[26];
+
+	snprintf_P(datestring, 
+			countof(datestring),
+			PSTR("%02u/%02u/%04u %02u:%02u:%02u"),
+			dt.Month(),
+			dt.Day(),
+			dt.Year(),
+			dt.Hour(),
+			dt.Minute(),
+			dt.Second() );
+    Serial.print(datestring);
+}
+